Error 170

Archive of Gamsworld Google Group
Post Reply
warkcrm
User
User
Posts: 1
Joined: 4 years ago

Error 170

Post by warkcrm »

Hi, i´m trying to solve this error, but i can´t and idk why
Can you help me please? :c
Thanks!



Btw, here's the code

Code: Select all

Sets
    i  "Plantas"  /Armenia,Pereira,Manizales /
    j  "Zonas"   /1,2,3,4,5/;
    

Table

T (i,j)  "Costo de transportar de la planta i a la zona j" 


        Armenia     Pereira     Manizales
    1      100        200         300
    2      120        150         200
    3      150        100         250
    4      200        180         150
    5      220        200         100 ;
    

Parameters

P(i)   Capacidad de produccion por planta (CajasXMes)

   /  Armenia          100000
      Pereira          120000
      Manizales        100000  /

D(j)    Demanda por zona (CajasXMes)

   / 1    75000
     2    50000
     3    50000
     4    55000
     5    80000  /;


Variables

W Función de costos;


Positive Variables

X (i,j) Número de cajas a enviar de Planta a Zona por mes ;

Equations

         Costo           Función Objetivo
         Produccion(i)   Se alcanza el límite de producción en la planta i
         Demanda(j)      Demanda satisfecha en la zona j ;


  Costo..                 W =E= sum( (i,j), T(i,j)* X(i,j) );
  Produccion(i)..         sum(j, X(i,j))  =l=   P(i);
  Demanda(j)..            sum(i, X(i,j))  =g=   D(j);



Model transport /all/;

Solve transport using LP minimizing W;
Freddy
User
User
Posts: 16
Joined: 5 years ago

Re: Error 170

Post by Freddy »

warkcrm,
the first dimension in a GAMS table is the row dimension. You need to swap the indices for the parameter T (or transpose the table) as so:

Code: Select all

Sets
    i  "Plantas"  /Armenia,Pereira,Manizales /
    j  "Zonas"   /1,2,3,4,5/;
    

Table

T (j,i)  "Costo de transportar de la planta i a la zona j" 


        Armenia     Pereira     Manizales
    1      100        200         300
    2      120        150         200
    3      150        100         250
    4      200        180         150
    5      220        200         100 ;
    

Parameters

P(i)   Capacidad de produccion por planta (CajasXMes)

   /  Armenia          100000
      Pereira          120000
      Manizales        100000  /

D(j)    Demanda por zona (CajasXMes)

   / 1    75000
     2    50000
     3    50000
     4    55000
     5    80000  /;


Variables

W Función de costos;


Positive Variables

X (i,j) Número de cajas a enviar de Planta a Zona por mes ;

Equations

         Costo           Función Objetivo
         Produccion(i)   Se alcanza el límite de producción en la planta i
         Demanda(j)      Demanda satisfecha en la zona j ;


  Costo..                 W =E= sum( (i,j), T(j,i)* X(i,j) );
  Produccion(i)..         sum(j, X(i,j))  =l=   P(i);
  Demanda(j)..            sum(i, X(i,j))  =g=   D(j);



Model transport /all/;

Solve transport using LP minimizing W;
Post Reply