How to make the variable PM(m,time) exogeneous

Problems with modeling
Post Reply
KANGAMBEGA18
User
User
Posts: 2
Joined: 1 year ago

How to make the variable PM(m,time) exogeneous

Post by KANGAMBEGA18 »

I need your help to make the variable PM(m,time) exogeneous in order to simulate a shock.
This is my EGC model:


VARIABLES

* 5.1.1 Volume variables
C(i,h,time) Consumption of commodity i by type h households
CG(i,time) Public final consumption of commodity i
CI(j,time) Total intermediate consumption of industry j
CMIN(i,h,time) Minimum consumption of commodity i by type h households
DD(i,time) Domestic demand for commodity i produced locally
DI(i,j,time) Intermediate consumption of commodity i by industry j
DIT(i,time) Total intermediate demand for commodity i
DS(j,i,time) Supply of commodity i by industry j to the domestic market
EX(j,x,time) Quantity of product x exported by industry j
EXD(x,time) World demand for exports of product x
IND(k,j,time) Investment in capital k for industry j
INV(i,time) Total final demand of commodity i for investment purposes (GFCF)
INV_PRI(i,time) Final demand of commodity i for private investment purposes
INV_PUB(i,time) Final demand of commodity i for public investment purposes
IM(m,time) Quantity of product m imported
KD(k,j,time) Demand for type k capital by industry j
KDC(j,time) Industry j demand for composite capital
KS(k,time) Supply of type k capital
LD(l,j,time) Demand for type l labor by industry j
LDC(j,time) Industry j demand for composite labor
LS(l,time) Supply of type l labor
MRGN(i,time) Demand for commodity i as a trade or transport margin
Q(i,time) Quantity demanded of composite commodity i
VA(j,time) Value added of industry j
VSTK(i,time) Inventory change of commodity i
XS(j,i,time) Industry j production of commodity i
XST(j,time) Total aggregate output of industry j

* 5.1.2 Price variables
e(time) Exchange rate (price of foreign currency in local currency)
IR(time) Interest rate
P(j,i,time) Basic price of industry j's production of commodity i
PC(i,time) Purchaser price of composite comodity i (including all taxes and margins)
PCI(j,time) Intermediate consumption price index of industry j
PD(i,time) Price of local product i sold on the domestic market (including all taxes and margins)
PE(x,time) Price received for exported commodity x (excluding export taxes)
PE_FOB(x,time) FOB price of exported commodity x (in local currency)
PIXCON(time) Chained consumer price index
PIXGDP(time) Chained GDP deflator
PIXGVT(time) Chained public expenditures price index
PIXINV_PRI(time) Chained private investment price index
PIXINV_PUB(time) Chained public investment price index
PK_PRI(time) Price of new private capital
PK_PUB(time) Price of new public capital
PL(i,time) Price of local product i (excluding all taxes on products)
PM(m,time) Price of imported product m (including all taxes and tariffs)
PP(j,time) Industry j unit cost including taxes directly related to the use of capital and labor but excluding other taxes on production
PT(j,time) Basic price of industry j's output
PVA(j,time) Price of industry j value added (including taxes on production directly related to the use of capital and labour)
PWM(m,time) World price of imported product m (expressed in foreign currency)
PWX(x,time) World price of exported product x (expressed in foreign currency)
R(k,j,time) Rental rate of type k capital in industry j
RC(j,time) Rental rate of industry j composite capital
RTI(k,j,time) Rental rate paid by industry j for type k capital including capital taxes
U(k,j,time) User cost of type k capital in industry j
W(l,time) Wage rate of type l labor
WC(j,time) Wage rate of industry j composite labor
WTI(l,j,time) Wage rate paid by industry j for type l labor including payroll taxes

* 5.1.3 Nominal (value) variables
CAB(time) Current account balance
CTH(h,time) Consumption budget of type h households
G(time) Current government expenditures on goods and services
GDP_BP(time) GDP at basic prices
GDP_FD(time) GDP at purchasers' prices from the perspective of final demand
GDP_IB(time) GDP at market prices (income-based)
GDP_MP(time) GDP at market prices
GFCF(time) Gross fixed capital formation
IT(time) Total investment expenditures
IT_PRI(time) Total private investment expenditures
IT_PUB(time) Total public investment expenditures
SF(f,time) Savings of type f businesses
SG(time) Government savings
SH(h,time) Savings of type h households
SROW(time) Rest-of-the-world savings
TDF(f,time) Income taxes of type f businesses
TDFT(time) Total government revenue from business income taxes
TDH(h,time) Income taxes of type h households
TDHT(time) Total government revenue from household income taxes
TIC(i,time) Government revenue from indirect taxes on product i
TICT(time) Total government receipts of indirect taxes on commodities
TIK(k,j,time) Government revenue from taxes on type k capital used by industry j
TIKT(time) Total government revenue from from taxes on capital
TIM(m,time) Government revenue from import duties on product m
TIMT(time) Total government revenue from import duties
TIP(j,time) Government revenue from taxes on industry j production (excluding taxes directly related to the use of capital and labor)
TIPT(time) Total government revenue from production taxes (excluding taxes directly related to the use of capital and labor)
TIW(l,j,time) Government revenue from payroll taxes on type l labor in industry j
TIWT(time) Total government revenue from payroll taxes
TIX(x,time) Government revenue from export taxes on product x
TIXT(time) Total government revenue from export taxes
TPRCTS(time) Total government revenue from taxes on products and imports
TPRODN(time) Total government revenue from other taxes on production
TR(ag,agj,time) Transfers from agent agj to agent ag
YDF(f,time) Disposable income of type f businesses
YDH(h,time) Disposable income of type h households
YF(f,time) Total income of type f businesses
YFK(f,time) Capital income of type f businesses
YFTR(f,time) Transfer income of type f businesses
YG(time) Total government income
YGK(time) Government capital income
YGTR(time) Government transfer income
YH(h,time) Total income of type h households
YHK(h,time) Capital income of type h households
YHL(h,time) Labor income of type h households
YHTR(h,time) Transfer income of type h households
YROW(time) Rest-of-the-world income

* 5.1.4 Rates and intercepts
sh0(h,time) Intercept (type h household savings)
sh1(h) Slope (type h household savings)
tr0(h,time) Intercept (transfers by type h households to governmentime)
tr1(h,time) Marginal rate of transfers by type h households to government
ttdf0(f,time) Intercept (income taxes of type f businesses)
ttdf1(f,time) Marginal income tax rate of type f businesses
ttdh0(h,time) Intercept (income taxes of type h households)
ttdh1(h,time) Marginal income tax rate of type h households
ttic(i,time) Tax rate on commodity i
ttik(k,j,time) Tax rate on type k capital used in industry j
ttim(m,time) Rate of taxes and duties on imports of commodity m
ttip(j,time) Tax rate on the production of industry j
ttiw(l,j,time) Tax rate on type l worker compensation in industry j
ttix(x,time) Export tax rate on exported commodity x
B_VAa(j,time) Total factor productivity sector j

*===============================================================================
un(l,time) Unemployment rate for labour L
*===============================================================================

* 5.1.5 Other variables
LEON(time) Excess supply on the last market
OMEGA Objective variable
;


* 5.2 Equation definition

EQUATIONS

EQ1(j,time) Value added demand in industry j (Leontief)
EQ2(j,time) Total intermediate consumption demand in industry j (Leontief)
EQ3(j,time) CES between of composite labor and capital
EQ3b(j,time) Value added equals labor for industries with no capital
* EQ3c(j,time)
EQ4(j,time) Relative demand for composite labor and capital by industry j(CES)
EQ5(j,time) CES between labor categories
EQ6(l,j,time) Demand for type l labor by industry j (CES)
EQ7(j,time) CES between capital categories
EQ8(k,j,time) Demand for type k capital by industry j (CES)
EQ9(i,j,time) Intermediate consumption of commodity i by industry j (Leontief)
EQ10(h,time) Total income of type h households
EQ11(h,time) Labor income of type h households
EQ12(h,time) Capital income of type h households
EQ13(h,time) Transfer income of type h households
EQ14(h,time) Disposable income of type h households
EQ15(h,time) Consumption budget of type h households
EQ16(h,time) Savings of type h households
EQ17(f,time) Total income of type f businesses
EQ18(f,time) Capital income of type f businesses
EQ19(f,time) Transfer income of type f businesses
EQ20(f,time) Disposable income of type f businesses
EQ21(f,time) Savings of type f businesses
EQ22(time) Total government income
EQ23(time) Government capital income
EQ24(time) Total government revenue from household income taxes
EQ25(time) Total government revenue from business income taxes
EQ26(time) Total government revenue from other taxes on production
EQ27(time) Total government receipts of indirect taxes on wages
EQ28(time) Total government receipts of indirect taxes on capital
EQ29(time) Total government revenue from production taxes
EQ30(time) Total government revenue from taxes on products and imports
EQ31(time) Total government receipts of indirect taxes on commodities
EQ32(time) Total government revenue from import duties
EQ33(time) Total government revenue from export taxes
EQ34(time) Government transfer income
EQ35(h,time) Income taxes of type h households
EQ36(f,time) Income taxes of type f businesses
EQ37(l,j,time) Government revenue from payroll taxes on type l labor in industry j
EQ38(k,j,time) Government revenue from taxes on type k capital used by industry j
EQ39(j,time) Government revenue from taxes on industry j production
EQ40(nm,time) Government revenue from indirect taxes on product nm
EQ41(m,time) Government revenue from indirect taxes on product m
EQ42(m,time) Government revenue from import duties on product m
EQ43(x,time) Government revenue from export taxes on product x
EQ44(time) Government savings
EQ45(time) Rest-of-the-world income
EQ46(time) Rest-of-the-world savings
EQ47(time) Equivalence between current account balance and ROW savings
EQ48(agng,h,time) Transfers from household h to agent agng
EQ49(h,time) Transfers from household h to government
EQ50(ag,f,time) Transfers from type f businesses to agent ag
EQ51(agng,time) Public transfers
EQ52(agd,time) Transfers from abroad
EQ53(i,h,time) Consumption of commodity i by type h households
EQ54(time) Gross fixed capital formation
EQ55(i,time) Final demand of commodity i for private investment purposes
EQ56(i,time) Final demand of commodity i for public investment purposes
EQ57(i,time) Total final demand of commodity i for investment purposes
EQ58(i,time) Public final consumption of commodity i
*EQ58(time)
EQ59(i,time) Total intermediate demand for commodity i
EQ60(i,time) Demand for commodity i as a trade or transport margin
EQ61(j,time) CET between different commodities produced by industry j
EQ62(j,i,time) Industry j production of commodity i (CEtime)
EQ63(j,x,time) CET between exports and local commodity
EQ64(j,nx,time) Equivalence between XS and DS for non exported commodities
EQ65(j,x,time) Relative supply of exports and local commodity (CEtime)
EQ65a(j,x,time) Equivalence between XS and DS for commodities only sold locally
EQ65b(j,x,time) Equivalence between XS and EX for commodities only exported
EQ66(x,time) World demand for exports of product x
EQ67(m,time) CES between imports and local production
EQ68(nm,time) Equivalence between Q and D for non importable
EQ69(m,time) Demand for imports (CES)
EQ70(j,time) Industry j unit cost
EQ71(j,time) Basic price of industry j's production of commodity i
EQ72(j,time) Intermediate consumption price index of industry j
EQ73(j,time) Price of industry j value added
* EQ74(j,time) Wage rate of industry j composite labor
EQ75(l,j,time) Wage rate paid by industry j for type l labor including payroll taxes
* EQ76(j,time) Rental rate of industry j composite capital
EQ77(k,j,time) Rental rate paid by industry j for type k capital including capital taxes
* EQ78(j,i,time) Total producer price
EQ78a(j,i,time) Total producer price is equal to P if there is only one product
EQ79(j,x,time) Basic price of industry j's production of commodity x
EQ80(j,nx,time) Equivalence between P and PL for non exportable
EQ81(x,time) Price received for exported commodity x (excluding export taxes)
EQ82(i,time) Price of local product i sold on the domestic market (including all taxes and margins)
* EQ83(m,time) Price of imported product m (including all taxes and tariffs)
EQ84(m,time) Purchaser price of composite comodity m
EQ85(nm,time) Equivalence between PC and PD for non imported commodities
EQ86(time) GDP deflator (Fischer index)
EQ87(time) Consumer price index (Laspeyres)
EQ88(time) Private investment price index
EQ89(time) Public investment price index
EQ90(time) Public expenditures price index
EQ91(i1,time) Domestic absorbtion
EQ92(l,time) Labor supply equals labour demand
EQ93(k,time) Capital supply equals capital demand
EQ94(time) Total investment equals total savings
EQ95(time) Private investment equals total investment less public investment
EQ96(i,time) Supply of domestic production equals demand
EQ97(x,time) International demand for exports equals supply
EQ98(time) GDP at basic prices
EQ99(time) GDP at market prices
EQ100(time) GDP at market prices (income-based)
EQ101(time) GDP at purchasers' prices from the perspective of final demand
* EQ102(k,j,time) Capital growth
EQ103(time) Total public investment
EQ104(time) Equilibrium on the private investment market
EQ105(time) Aggregate private price of capital
EQ106(time) Aggregate public price of capital
EQ107(k,bus,time) Investment demand by private industry
EQ108a(k,bus,time) User cost of capital (private sectors)
EQ108b(k,pub,time) User cost of capital (public sectors)
*===============================================================================
EQ109(l,time) Unemployment function
*===============================================================================

WALRAS(time) Walras law verification
OBJ Objective function
;

* 5.3 Equations

* 5.3.1 Production

EQ1(j,t).. VA(j,t) =e= v(j)*XST(j,t);

EQ2(j,t).. CI(j,t) =e= io(j)*XST(j,t);

EQ3(j,t)$KDCO(J)..
VA(j,t) =e= B_VA(j)*[beta_VA(j)*LDC(j,t)**(-rho_VA(j))+
(1-beta_VA(j))*KDC(j,t)**(-rho_VA(j))]
**(-1/rho_VA(j));

EQ3b(j,t)$(KDCO(J) EQ 0)..
VA(j,t) =e= LDC(j,t);

* EQ3c(j,t)$(LDCO(J) EQ 0)..
* VA(j,t) =e= KDC(j,t);

EQ4(j,t)$[LDCO(j)and KDCO(j)]..
LDC(j,t) =e= {[beta_VA(j)/(1-beta_VA(j))]*[RC(j,t)/WC(j,t)]}
**sigma_VA(j)*KDC(j,t);

EQ5(j,t)$LDCO(j).. LDC(j,t) =e= B_LD(j)*SUM[l$LDO(l,j),beta_LD(l,j)*LD(l,j,t)
**(-rho_LD(j))]**(-1/rho_LD(j));

EQ6(l,j,t)$LDO(l,j)..
LD(l,j,t) =e= [beta_LD(l,j)*WC(j,t)/WTI(l,j,t)]**sigma_LD(j)
*B_LD(j)**(sigma_LD(j)-1)*LDC(j,t);

EQ7(j,t)$KDCO(j)..
KDC(j,t) =e= B_KD(j)*SUM[k$KDO(k,j),beta_KD(k,j)*KD(k,j,t)
**(-rho_KD(j))]**(-1/rho_KD(j));

EQ8(k,j,t)$KDO(k,j)..
KD(k,j,t) =e= [beta_KD(k,j)*RC(j,t)/RTI(k,j,t)]**sigma_KD(j)
*B_KD(j)**(sigma_KD(j)-1)*KDC(j,t);


EQ9(i,j,t).. DI(i,j,t) =e= aij(i,j)*CI(j,t);

* 5.3.2 Income and savings
* 5.3.2.1 Households

EQ10(h,t).. YH(h,t) =e= YHL(h,t)+YHK(h,t)+YHTR(h,t);

EQ11(h,t).. YHL(h,t) =e= SUM[l,lambda_WL(h,l)*W(l,t)
*SUM(j$LDO(l,j),LD(l,j,t))];

EQ12(h,t).. YHK(h,t) =e= SUM[k,lambda_RK(h,k)*SUM(j$KDO(k,j),
R(k,j,t)*KD(k,j,t))];

EQ13(h,t).. YHTR(h,t) =e= SUM[ag,TR(h,ag,t)];

EQ14(h,t).. YDH(h,t) =e= YH(h,t)-TDH(h,t)-TR('gvt',h,t);

EQ15(h,t).. CTH(h,t) =e= YDH(h,t)-SH(h,t)-SUM[agng,TR(agng,h,t)];

EQ16(h,t).. SH(h,t) =e= PIXCON(t)**eta*sh0(h,t)+sh1(h)*YDH(h,t);


* 5.3.2.2 Firms

EQ17(f,t).. YF(f,t) =e= YFK(f,t)+YFTR(f,t);

EQ18(f,t).. YFK(f,t) =e= SUM[k,lambda_RK(f,k)*SUM(j$KDO(k,j),R(k,j,t)*KD(k,j,t))];

EQ19(f,t).. YFTR(f,t) =e= SUM[ag,TR(f,ag,t)];

EQ20(f,t).. YDF(f,t) =e= YF(f,t)-TDF(f,t);

EQ21(f,t).. SF(f,t) =e= YDF(f,t)-SUM[ag,TR(ag,f,t)];

* 5.3.2.3 Government

EQ22(t).. YG(t) =e= YGK(t)+TDHT(t)+TDFT(t)+TPRODN(t)+TPRCTS(t)+YGTR(t);

EQ23(t).. YGK(t) =e= SUM[k,lambda_RK('gvt',k)*SUM(j$KDO(k,j),R(k,j,t)*KD(k,j,t))];

EQ24(t).. TDHT(t) =e= SUM[h,TDH(h,t)];

EQ25(t).. TDFT(t) =e= SUM[f,TDF(f,t)];

EQ26(t).. TPRODN(t) =e= TIWT(t)+TIKT(t)+TIPT(t);

EQ27(t).. TIWT(t) =e= SUM[(l,j)$LDO(l,j),TIW(l,j,t)];

EQ28(t).. TIKT(t) =e= SUM[(k,j)$KDO(k,j),TIK(k,j,t)];

EQ29(t).. TIPT(t) =e= SUM[j,TIP(j,t)];

EQ30(t).. TPRCTS(t) =e= TICT(t)+TIMT(t)+TIXT(t);

EQ31(t).. TICT(t) =e= SUM[i,TIC(i,t)];

EQ32(t).. TIMT(t) =e= SUM[m,TIM(m,t)];

EQ33(t).. TIXT(t) =e= SUM[x,TIX(x,t)];

EQ34(t).. YGTR(t) =e= SUM[agng,TR('gvt',agng,t)];

EQ35(h,t).. TDH(h,t) =e= PIXCON(t)**eta*ttdh0(h,t)+ttdh1(h,t)*YH(h,t);

EQ36(f,t).. TDF(f,t) =e= PIXCON(t)**eta*ttdf0(f,t)+ttdf1(f,t)*YFK(f,t);

EQ37(l,j,t)$LDO(l,j)..
TIW(l,j,t) =e= ttiw(l,j,t)*W(l,t)*LD(l,j,t);

EQ38(k,j,t)$KDO(k,j)..
TIK(k,j,t) =e= ttik(k,j,t)*R(k,j,t)*KD(k,j,t);

EQ39(j,t).. TIP(j,t) =e= ttip(j,t)*PP(j,t)*XST(j,t);

EQ40(nm,t).. TIC(nm,t) =e= ttic(nm,t)*(PL(nm,t)+SUM[i,PC(i,t)*tmrg(i,nm)])
*DD(nm,t);

EQ41(m,t).. TIC(m,t) =e= ttic(m,t)*[(PL(m,t)+SUM[i,PC(i,t)*tmrg(i,m)])
*DD(m,t)+((1+ttim(m,t))*PWM(m,t)*e(t)
+SUM[i,PC(i,t)*tmrg(i,m)])*IM(m,t)];

EQ42(m,t).. TIM(m,t) =e= ttim(m,t)*PWM(m,t)*e(t)*IM(m,t);

EQ43(x,t).. TIX(x,t) =e= ttix(x,t)*(PE(x,t)+SUM[i,PC(i,t)*tmrg_X(i,x)])
*EXD(x,t);

EQ44(t).. SG(t) =e= YG(t)-SUM[agng,TR(agng,'gvt',t)]-G(t);

* 5.3.2.4 Rest of the world

EQ45(t).. YROW(t) =e= e(t)*SUM[m,PWM(m,t)*IM(m,t)]
+SUM[k,lambda_RK('row',k)*SUM(j$KDO(k,j),R(k,j,t)*KD(k,j,t))]
+SUM[agd,TR('row',agd,t)]+SUM[l,lambda_WL('row',l)*W(l,t)
*SUM(j$LDO(l,j),LD(l,j,t))];

EQ46(t).. SROW(t) =e= YROW(t)-SUM[x,PE_FOB(x,t)*EXD(x,t)]-SUM[agd,TR(agd,'row',t)];

EQ47(t).. SROW(t) =e= -CAB(t);

* 5.3.2.5 Transfers

EQ48(agng,h,t).. TR(agng,h,t) =e= lambda_TR(agng,h)*YDH(h,t);

EQ49(h,t).. TR('gvt',h,t) =e= PIXCON(t)**eta*tr0(h,t)+tr1(h,t)*YH(h,t);

EQ50(ag,f,t).. TR(ag,f,t) =e= lambda_TR(ag,f)*YDF(f,t);

EQ51(agng,t).. TR(agng,'gvt',t) =e= PIXCON(t)**eta*TRO(agng,'gvt')*pop(t);

EQ52(agd,t).. TR(agd,'row',t) =e= PIXCON(t)**eta*TRO(agd,'row')*pop(t);


* 5.3.3 Demand

EQ53(i,h,t).. C(i,h,t)*PC(i,t) =e= CMIN(i,h,t)*PC(i,t)+gamma_LES(i,h)*{CTH(h,t)-
SUM[ij,CMIN(ij,h,t)*PC(ij,t)]};

EQ54(t).. GFCF(t) =e= IT(t)-SUM[i,PC(i,t)*VSTK(i,t)];

EQ55(i,t).. INV_PRI(i,t)*PC(i,t) =e= gamma_INVPRI(i)*IT_PRI(t);

EQ56(i,t).. INV_PUB(i,t)*PC(i,t) =e= gamma_INVPUB(i)*IT_PUB(t);

EQ57(i,t).. INV(i,t) =e= INV_PRI(i,t)+INV_PUB(i,t);

EQ58(i,t).. CG(i,t)*PC(i,t) =e= gamma_GVT(i)*G(t);
*Transformer cette équation en
*EQ58(t).. G(t)=e= SUM[i, CG(i,t)*PC(i,t)];

EQ59(i,t).. DIT(i,t) =e= SUM[j,DI(i,j,t)];

EQ60(i,t).. MRGN(i,t) =e= SUM[ij,tmrg(i,ij)*DD(ij,t)]+
SUM[m,tmrg(i,m)*IM(m,t)]+
SUM[x,tmrg_X(i,x)*EXD(x,t)];


* 5.3.4 International trade

EQ61(j,t).. XST(j,t) =e= B_XT(j)*SUM[i$XSO(j,i),beta_XT(j,i)*XS(j,i,t)
**rho_XT(j)]**(1/rho_XT(j));

EQ62(j,i,t)$(XSO(j,i) and (XSO(j,i) ne XSTO(j)))..
XS(j,i,t) =e= XST(j,t)/B_XT(j)**(1+sigma_XT(j))*
{P(j,i,t)/[beta_XT(j,i)*PT(j,t)]}**sigma_XT(j);

EQ63(j,x,t)$(EXO(j,x) and DSO(j,x))..
XS(j,x,t) =e= B_X(j,x)*[beta_X(j,x)*EX(j,x,t)**rho_X(j,x)
+(1-beta_X(j,x))*DS(j,x,t)**rho_X(j,x)]
**(1/rho_X(j,x));

EQ64(j,nx,t)$XSO(j,nx)..
XS(j,nx,t) =e= DS(j,nx,t);

EQ65(j,x,t)$(EXO(j,x) and DSO(j,x))..
EX(j,x,t) =e= {[(1-beta_X(j,x))/beta_X(j,x)]*[PE(x,t)/PL(x,t)]}
**sigma_X(j,x)*DS(j,x,t);

EQ65a(j,x,t)$((EXO(j,x) eq 0) and DSO(j,x))..
XS(j,x,t) =e= DS(j,x,t);

EQ65b(j,x,t)$(EXO(j,x) and (DSO(j,x) eq 0))..
XS(j,x,t) =e= EX(j,x,t);

EQ66(x,t).. EXD(x,t) =e= EXDO(x)*pop(t)*[e(t)*PWX(x,t)/PE_fob(x,t)]
**sigma_XD(x);

EQ67(m,t).. Q(m,t) =e= B_M(m)*[beta_M(m)*IM(m,t)**(-rho_M(M))+(1-beta_M(m))
*DD(m,t)**(-rho_M(M))]**(-1/rho_M(M));

EQ68(nm,t).. Q(nm,t) =e= DD(nm,t);

EQ69(m,t).. IM(m,t) =e= {[beta_M(m)/(1-beta_M(m))]*[PD(m,t)/PM(m,t)]}
**sigma_M(m)*DD(m,t);

* 5.3.5 Prices

EQ70(j,t).. PP(j,t)*XST(j,t) =e= PVA(j,t)*VA(j,t)+PCI(j,t)*CI(j,t);

EQ71(j,t).. PT(j,t) =e= (1+ttip(j,t))*PP(j,t);

EQ72(j,t).. PCI(j,t)*CI(j,t) =e= SUM[i,PC(i,t)*DI(i,j,t)];

EQ73(j,t).. PVA(j,t)*VA(j,t) =e= WC(j,t)*LDC(j,t)+RC(j,t)*KDC(j,t)$KDCO(j);

* Given the way equation 6 is written, equation 74 is redundant
* EQ74(j,t).. WC(j,t)*LDC(j,t) =e= SUM[l$LDO(l,j),WTI(l,j,t)*LD(l,j,t)];

EQ75(l,j,t)$LDO(l,j)..
WTI(l,j,t) =e= W(l,t)*(1+ttiw(l,j,t));

* Given the way equation 8 is written, equation 76 is redundant
* EQ76(j,t).. RC(j,t)*KDC(j,t) =e= SUM[k$KDO(k,j),RTI(k,j,t)*KD(k,j,t)];

EQ77(k,j,t)$KDO(k,j)..
RTI(k,j,t) =e= R(k,j,t)*(1+ttik(k,j,t));

* Given the way equation 62 is written, equation 78 is redundant if
* a sector produces more than one commodity
* EQ78(j,t).. PT(j,t)*XST(j,t) =e= SUM[i,P(j,i,t)*XS(j,i,t)];

EQ78a(j,i,t)$(XSO(j,i) eq XSTO(j))..
P(j,i,t) =e= PT(j,t);

EQ79(j,x,t)$XSO(j,x)..
P(j,x,t)*XS(j,x,t) =e= PE(x,t)*EX(j,x,t)$EXO(j,x)
+PL(x,t)*DS(j,x,t)$DSO(j,x);

EQ80(j,nx,t)$XSO(j,nx)..
P(j,nx,t) =e= PL(nx,t);

EQ81(x,t).. PE_FOB(x,t) =e= (PE(x,t)+SUM[i,PC(i,t)*tmrg_X(i,x)])*(1+ttix(x,t));

EQ82(i,t).. PD(i,t) =e= (1+ttic(i,t))*(PL(i,t)+SUM[ij,PC(ij,t)*tmrg(ij,i)]);

* EQ83(m,t).. PM(m,t) =e= (1+ttic(m,t))*{(1+ttim(m,t))*e(t)*PWM(m,t)
* +SUM[i,PC(i,t)*tmrg(i,m)]};


EQ84(m,t).. PC(m,t)*Q(m,t) =e= PM(m,t)*IM(m,t)+PD(m,t)*DD(m,t);

EQ85(nm,t).. PC(nm,t) =e= PD(nm,t);

EQ86(t).. PIXGDP(t) =e= {SUM[j,PVA(j,t)*VAO(j)]/SUM[j,PVAO(j)*VAO(j)]*
SUM[j,PVA(j,t)*VA(j,t)]/SUM[j,PVAO(j)*VA(j,t)]}**0.5;

EQ87(t).. PIXCON(t) =e= SUM[i,PC(i,t)*SUM[h,CO(i,h)]]
/SUM[i,PCO(i)*SUM[h,CO(i,h)]];

EQ88(t).. PIXINV_PRI(t) =e= PROD[i$gamma_INVPRI(i),(PC(i,t)/PCO(i))
**gamma_INVPRI(i)];

EQ89(t).. PIXINV_PUB(t) =e= PROD[i$gamma_INVPUB(i),(PC(i,t)/PCO(i))
**gamma_INVPUB(i)];

EQ90(t).. PIXGVT(t) =e= PROD[i$gamma_GVT(i),(PC(i,t)/PCO(i))**gamma_GVT(i)];

* 5.3.6 Equilibrium

EQ91(i1,t).. Q(i1,t) =e= SUM[h,C(i1,h,t)]+CG(i1,t)+INV(i1,t)+VSTK(i1,t)+
DIT(i1,t)+MRGN(i1,t);

*===============================================================================
* EQ92(l,t).. LS(l,t) =e= SUM[j$LDO(l,j),LD(l,j,t)];
EQ92(l,t).. LS(l,t) =e= SUM[j$LDO(l,j),LD(l,j,t)]/(1-un(l,t));
*===============================================================================

EQ93(k,t).. KS(k,t) =e= SUM[j$KDO(k,j),KD(k,j,t)];

EQ94(t).. IT(t) =e= SUM[h,SH(h,t)]+SUM[f,SF(f,t)]+SG(t)+SROW(t);

EQ95(t).. IT_PRI(t) =e= IT(t)-IT_PUB(t)-SUM[i,PC(i,t)*VSTK(i,t)];

EQ96(i,t).. SUM[j$DSO(j,i),DS(j,i,t)] =e= DD(i,t);

EQ97(x,t).. SUM[j$EXO(j,x),EX(j,x,t)] =e= EXD(x,t);


* 5.3.7 Gross domestic product

EQ98(t).. GDP_BP(t) =e= SUM[j,PVA(j,t)*VA(j,t)]+TIPT(t);

EQ99(t).. GDP_MP(t) =e= GDP_BP(t)+TPRCTS(t);

EQ100(t).. GDP_IB(t) =e= SUM[(l,j)$LDO(l,j),W(l,t)*LD(l,j,t)]
+SUM[(k,j)$KDO(k,j),R(k,j,t)*KD(k,j,t)]
+TPRODN(t)+TPRCTS(t);

EQ101(t).. GDP_FD(t) =e= SUM[i,PC(i,t)*(SUM[h,C(i,h,t)]+CG(i,t)+INV(i,t)
+VSTK(i,t))]+SUM[x,PE_FOB(x,t)*EXD(x,t)]
-SUM[m,PWM(m,t)*e(t)*IM(m,t)];

* 5.3.8 Dynamic equations

* EQ102(k,j,t+1)$KDO(k,j)..
* KD(k,j,t+1) =e= KD(k,j,t)*(1-delta(k,j))+IND(k,j,t);

EQ103(t).. IT_PUB(t) =e= PK_PUB(t)*SUM[(k,pub)$KDO(k,pub),IND(k,pub,t)];

EQ104(t).. IT_PRI(t) =e= PK_PRI(t)*SUM[(k,bus)$KDO(k,bus),IND(k,bus,t)];

EQ105(t).. PK_PRI(t) =e= 1/A_K_BUS*PROD[i$gamma_INVPRI(i),(PC(i,t)/gamma_INVPRI(i))
**gamma_INVPRI(i)];

EQ106(t).. PK_PUB(t) =e= 1/A_K_PUB*PROD[i$gamma_INVPUB(i),(PC(i,t)/gamma_INVPUB(i))
**gamma_INVPUB(i)];
EQ107(k,bus,t)$KDO(k,bus)..
IND(k,bus,t) =e= phi(k,bus)*[R(k,bus,t)/U(k,bus,t)]
**sigma_INV(k,bus)*KD(k,bus,t);

EQ108a(k,bus,t)$KDO(k,bus)..
U(k,bus,t) =e= PK_PRI(t)*(delta(k,bus)+ir(t));

EQ108b(k,pub,t)$KDO(k,pub)..
U(k,pub,t) =e= PK_PUB(t)*(delta(k,pub)+ir(t));

*===============================================================================
EQ109(l,t).. un(l,t) =e= A_un(l)*((w(l,t)/PIXCON(t)))**sig_un(l);
*===============================================================================

* 5.3.9 Other

WALRAS(t).. LEON(t) =e= Q('CEREA',t)-SUM[h,C('CEREA',h,t)]-CG('CEREA',t)
-INV('CEREA',t)-VSTK('CEREA',t)-DIT('CEREA',t)
-MRGN('CEREA',t);

OBJ.. OMEGA =e= 1;


* 6 Resolution
OPTION NLP = conopt4
MODEL PEPBASE STANDARD DYNAMIC MODEL /ALL/;
PEPBASE.HOLDFIXED=1;

* 6.1 BAU
* First the model must be solved for the BAU. This is specially important
* if the BAU does not follow a balanced growth path in which all prices remain
* constant and other variables grow at the same constant rate as the popula-
* tion. If the BAU is not a balanced growth scenario, then, except for the
* first period, variables cannot be initialised at their exact BAU values
* without solving the model. So GAMS computes the values of each variable
* for each period through this first numerical resolution.


LOOP[time,
T(time) = YES;
* 6.1.1 Variable initialisation
C.l(i,h,time) = CO(i,h)*pop(time);
CAB.l(time) = CABO*pop(time);
CG.l(i,time) = CGO(i)*pop(time);
CI.l(j,time) = CIO(j)*pop(time);
CMIN.l(i,h,time) = CMINO(i,h)*pop(time);
CTH.l(h,time) = CTHO(h)*pop(time);
DD.l(i,time) = DDO(i)*pop(time);
DI.l(i,j,time) = DIO(i,j)*pop(time);
DIT.l(i,time) = DITO(i)*pop(time);
DS.l(j,i,time) = DSO(j,i)*pop(time);
e.l(time) = eO;
EX.l(j,x,time) = EXO(j,x)*pop(time);
EXD.l(x,time) = EXDO(x)*pop(time);
G.l(time) = GO*pop(time);
*===============================================================================
*-------Hypothese de taux de croissance regulier du PIB-------------------------
GDP_BP.l(time) = GDP_BPO*pop(time);
GDP_FD.l(time) = GDP_FDO*pop(time);
GDP_IB.l(time) = GDP_IBO*pop(time);
GDP_MP.l(time) = GDP_MPO*pop(time);

*--------------Hypothese de taux de croissance observe et prevu du PIB----------
* GDP_BP.l(time+1) = GDP_BPO*(1+gr(time));
* GDP_FD.l(time+1) = GDP_FDO*(1+gr(time));
* GDP_IB.l(time+1) = GDP_IBO*(1+gr(time));
* GDP_MP.l(time+1) = GDP_MPO*(1+gr(time));
*===============================================================================

GFCF.l(time) = GFCFO*pop(time);
IM.l(m,time) = IMO(m)*pop(time);
IND.l(k,j,time) = INDO(k,j)*pop(time);
INV.l(i,time) = INVO(i)*pop(time);
INV_PRI.l(i,time) = INV_PRIO(i)*pop(time);
INV_PUB.l(i,time) = INV_PUBO(i)*pop(time);
IR.l(time) = IRO;
IT.l(time) = ITO*pop(time);
IT_PRI.l(time) = IT_PRIO*pop(time);
IT_PUB.l(time) = IT_PUBO*pop(time);
KDC.l(j,time) = KDCO(j)*pop(time);
KS.l(k,time) = KSO(k)*pop(time);
LD.l(l,j,time) = LDO(l,j)*pop(time);
LD.LO(l,j,time) = 0.00000000000000000001;
LDC.l(j,time) = LDCO(j)*pop(time);
LDC.LO(j,time) = 0.00000000000000000001;
LS.l(l,time) = LSO(l)*pop(time);
MRGN.l(i,time) = MRGNO(i)*pop(time);
P.l(j,i,time) = PO(j,i);
PC.l(i,time) = PCO(i);
PCI.l(j,time) = PCIO(j);
PD.l(i,time) = PDO(i);
PE.l(x,time) = PEO(x);
PE_FOB.l(x,time) = PE_FOBO(x);
PIXCON.l(time) = PIXCONO;
PIXGDP.l(time) = PIXGDPO;
PIXGVT.l(time) = PIXGVTO;
PIXINV_PRI.l(time) = PIXINV_PRIO;
PIXINV_PUB.l(time) = PIXINV_PUBO;
PK_PRI.l(time) = PK_PRIO;
PK_PUB.l(time) = PK_PUBO;
PL.l(i,time) = PLO(i);
PM.l(m,time) = PMO(m);
PP.l(j,time) = PPO(j);
PT.l(j,time) = PTO(j);
PVA.l(j,time) = PVAO(j);
PWM.l(m,time) = PWMO(m);
PWX.l(x,time) = PWXO(x);
Q.l(i,time) = QO(i)*pop(time);
R.l(k,j,time) = RO(k,j);
RC.l(j,time) = RCO(j);
RTI.l(k,j,time) = RTIO(k,j);
SF.l(f,time) = SFO(f)*pop(time);
SG.l(time) = SGO*pop(time);
SH.l(h,time) = SHO(h)*pop(time);
SROW.l(time) = SROWO*pop(time);
TDF.l(f,time) = TDFO(f)*pop(time);
TDFT.l(time) = TDFTO*pop(time);
TDH.l(h,time) = TDHO(h)*pop(time);
TDHT.l(time) = TDHTO*pop(time);
TIC.l(i,time) = TICO(i)*pop(time);
TICT.l(time) = TICTO*pop(time);
TIK.l(k,j,time) = TIKO(k,j)*pop(time);
TIKT.l(time) = TIKTO*pop(time);
TIM.l(m,time) = TIMO(m)*pop(time);
TIMT.l(time) = TIMTO*pop(time);
TIP.l(j,time) = TIPO(j)*pop(time);
TIPT.l(time) = TIPTO*pop(time);
TIW.l(l,j,time) = TIWO(l,j)*pop(time);
TIWT.l(time) = TIWTO*pop(time);
TIX.l(x,time) = TIXO(x)*pop(time);
TIXT.l(time) = TIXTO*pop(time);
TPRODN.l(time) = TPRODNO*pop(time);
TPRCTS.l(time) = TPRCTSO*pop(time);
TR.l(ag,agj,time) = TRO(ag,agj)*pop(time);
TR.l(agd,'row',time)
= TRO(agd,'row')*PIXCONO**eta*pop(time);
TR.l(agng,'gvt',time)
= TRO(agng,'gvt')*PIXCONO**eta*pop(time);
VA.l(j,time) = VAO(j)*pop(time);
VSTK.l(i,time) = VSTKO(i)*pop(time);
WC.l(j,time) = WCO(j);
W.l(l,time) = WO(l);
WTI.l(l,j,time) = WTIO(l,j);
U.l(k,j,time) = UO(k,j);
XS.l(j,i,time) = XSO(j,i)*pop(time);
XST.l(j,time) = XSTO(j)*pop(time);
YDF.l(f,time) = YDFO(f)*pop(time);
YDH.l(h,time) = YDHO(h)*pop(time);
YF.l(f,time) = YFO(f)*pop(time);
YFK.l(f,time) = YFKO(f)*pop(time);
YFTR.l(f,time) = YFTRO(f)*pop(time);
YG.l(time) = YGO*pop(time);
YGK.l(time) = YGKO*pop(time);
YGTR.l(time) = YGTRO*pop(time);
YH.l(h,time) = YHO(h)*pop(time);
YHK.l(h,time) = YHKO(h)*pop(time);
YHL.l(h,time) = YHLO(h)*pop(time);
YHTR.l(h,time) = YHTRO(h)*pop(time);
YROW.l(time) = YROWO*pop(time);
OMEGA.l = 1;

un.l(l,time) = uno(l);

* 6.1.2 Closures
* The numeraire is the nominal exchange rate
e.fx(time) = 1;
CAB.fx(time) = CABO*pop(time);
CMIN.fx(i,h,time) = CMINO(i,h)*pop(time);
G.fx(time) = GO*pop(time);
*CG.fx(i,time) = CGO(i)*pop(time);
IND.fx(k,pub,time)$KDO(k,pub)
= INDO(k,pub)*pop(time);
KD.fx(k,j,time)$(KDO(k,j) and (ord(time) eq 1))
= KDO(k,j);
KD.fx(k,j,time)$(ord(time) gt 1)
= KD.l(k,j,time-1)*(1-delta(k,j))+IND.l(k,j,time-1);
LS.fx(l,time) = LSO(l)*pop(time);
PWM.fx(m,time) = PWMO(m);
PWX.fx(x,time) = PWXO(x);
VSTK.fx(i,time) = VSTKO(i)*pop(time);

* 6.1.3 Rates and intercepts
sh0.fx(h,time) = sh0O(h)*pop(time);
sh1.fx(h) = sh1O(h);
tr0.fx(h,time) = tr0O(h)*pop(time);
tr1.fx(h,time) = tr1O(h);
ttdf0.fx(f,time) = ttdf0O(f)*pop(time);
ttdf1.fx(f,time) = ttdf1O(f);
ttdh0.fx(h,time) = ttdh0O(h)*pop(time);
ttdh1.fx(h,time) = ttdh1O(h);
ttic.fx(i,time) = tticO(i);
ttik.fx(k,j,time) = ttikO(k,j);
ttim.fx(m,time) = ttimO(m);
ttip.fx(j,time) = ttipO(j);
ttiw.fx(l,j,time) = ttiwO(l,j);
ttix.fx(x,time) = ttixO(x);

B_VAa.fx(j,time) = B_VA(j);

* 6.1.4 Resolution
OPTION NLP=CONOPT4;
OPTION LIMROW=1;

SOLVE PEPBASE USING CNS;
T(time) = NO;
];
*$Exit
$include RESULTS_BAU19
Post Reply